Previous Thread
Next Thread
Print Thread
Joined: Feb 2006
Posts: 23
M
Forum Member
OP Offline
Forum Member
M
Joined: Feb 2006
Posts: 23
Hello,
I am using coor orient rms to orient a section of my protein on top of the same section from another protein, and despite having coordinates in the comparison and main set for the atoms of interest, I am getting a warning:
CHARMM> coor orient rms sele coil end
SELRPN> 550 atoms have been selected out of 10825
**WARNING** ALL SELECTED COORDINATES UNDEFINED

**** WARNING **** FOR THIS OPERATION, THERE WERE 550 MISSING COORDINATES

and the protein does not align. I am pasting my input text below in hopes that someone might notice any sequence that may be problematic. Thank you.

! Read in topology parameter definitions and add zincpatch
read rtf card name /data6/c/jasonwan/charmm/toppar/top_all22_prot.inp
read param card name /data6/c/jasonwan/charmm/toppar/par_all22_prot.inp
read rtf card APPEND name /data6/c/jasonwan/charmm/toppar/patchtest/toppar_all22_prot_zincpatch.inp

read univ
* modified pdb setup
*
pdb
w 61 6
end


open unit 21 read form name /data6/c/jasonwan/models/1ca9.c
read sequence pdb unit 21
gener 1CA9 first NTER last CTER setup warn
rewind unit 21
read coor univ unit 21 offset 0
close unit 21

open unit 22 read form name /data6/c/jasonwan/models/1cb9.c
read sequence pdb unit 22
gener 1CB9 first NTER last CTER setup warn
rewind unit 22
read coor univ unit 22 offset 191
close unit 22

open unit 23 read form name /data6/c/jasonwan/models/1cc9.c
read sequence pdb unit 23
gener 1CC9 first NTER last CTER setup warn
rewind unit 23
read coor univ unit 23 offset 382
close unit 23

ic param ! GET MISSING BONDS AND ANGLES FROM PARAMETER FILE
ic purge ! CLEAN UP THE IC TABLE
ic fill preserve ! RECOMPUTE IC VALUES FROM COORDS
ic build ! PLACE ANY MISSING COORDS, E.G. TERMINAL O ON CO2-
ic fill
update

! Orient 1CA9 trimer w/ XYaxis
coor orient mass sele ires 3 : 36 .and. segid 1CA9 .or. ires 3 : 36 .and. segid 1CB9 .or. ires 3 : 36 .and. segid 1CC9 end

! temp save to see how trimer centered
write coor pdb name 1cabc9_x.crd.pdb
* 1CABC9 three chains align x
*

! remove the other two chains
Delete atoms sele segid 1CB9 end
Delete atoms sele segid 1CC9 end

! Save chain 1CA9
! Write PSF and CRD
write psf card name 1ca9_x.psf
* 1CA9 chain A align x
*
write coor card name 1ca9_x.crd
* 1CA9 chain A align x
*
write coor pdb name 1ca9_x.crd.pdb
* 1CA9 chain A align x
*


! Save coordinates also in comparsion coordinate set for later use
!coor copy comp
coor copy comp sele ires 3 : 36 .and. segid 1CA9 show end

! do you need to remove the 1CA9 chain here?
!Delete atoms sele segid 1CA9 end


! read in model
open unit 21 read form name /data6/c/jasonwan/models/model5b6a.chh
read sequence pdb unit 21
gener 5b6A first NTER last CTER setup warn
rewind unit 21
read coor univ unit 21 offset 191
close unit 21

! check to see if we have it all (except the hydrogens)
print coor select .not. hydrogen .and. .not. initialized end

ic param ! GET MISSING BONDS AND ANGLES FROM PARAMETER FILE
ic purge ! CLEAN UP THE IC TABLE
ic fill preserve ! RECOMPUTE IC VALUES FROM COORDS
ic build ! PLACE ANY MISSING COORDS, E.G. TERMINAL O ON CO2-
hbuild sele segid 5b6A .and. type H* show end !(RE)CONSTRUCT H ATOMS; ROTATE -OH and -CH3
update

print coor

! Orient kinked coil w/ 1CA9 monomer
define coil sele segid 5b6A .and. ires 504 : 537 show end
coor orient rms sele coil end

Joined: Sep 2003
Posts: 8,621
Likes: 24
rmv Online Content
Forum Member
Online Content
Forum Member
Joined: Sep 2003
Posts: 8,621
Likes: 24
Check for more informative messages earlier in your output.


Rick Venable
computational chemist

Joined: Sep 2003
Posts: 4,860
Likes: 10
Forum Member
Online Content
Forum Member
Joined: Sep 2003
Posts: 4,860
Likes: 10
I think you have generated one PSF containing pieces from two different proteins. It is not at all clear to me that you actually have coordinates that can be compared. CHARMM is not too happy about handling two different proteins at the same time; this would require quite a bit of tweaking (one PSF and two conformations is OK though).
To simplify matters I would recommend that you create your PSF first and then write two CHARMM coordinate files (one for each structure). Finally run a separate job to compare the two. "divide and conquer" remains the basic rule of troubleshooting.


Lennart Nilsson
Karolinska Institutet
Stockholm, Sweden
Joined: Sep 2003
Posts: 8,621
Likes: 24
rmv Online Content
Forum Member
Online Content
Forum Member
Joined: Sep 2003
Posts: 8,621
Likes: 24
It's possible to do what you're attempting, but not that way.

Since the COOR COPY COMP command was before you added a new segment, the later COOR ORIE RMS will fail because there are no coords for the new segment in the COMP set. After generating the new segment, you need to do something like

coor copy comp ! COPY ALL ATOMS
coor dupl comp sele atoms-from-protein1 end sele atoms-from-protein2 end
coor orient rms sele atoms-from-protein2 end

where atoms-from-protein1 etc. is some atom selection that identifies the matching regions. Note that the number of atoms and their correspondence in the two atom selections must be exact. If the amino acid sequences are not identical, you must explicitly account for that by the atom selections (e.g. limit to backbone).


Rick Venable
computational chemist

Joined: Feb 2006
Posts: 23
M
Forum Member
OP Offline
Forum Member
M
Joined: Feb 2006
Posts: 23
The coor dupl comp after generating all the segments did exactly what I wanted for the orientation.
I had also started breaking up the input scripts for the divide and conquer method before finding the aforementioned worked. Thank you both!

By the way, what does the dupl do- does it let the comp set have two different coord sets?

Last edited by metalman; 02/24/06 03:44 PM.
Joined: Feb 2006
Posts: 23
M
Forum Member
OP Offline
Forum Member
M
Joined: Feb 2006
Posts: 23
8) The DUPLicate command.

The DUPLicate command copies coordinates between atoms within
a structure. The coordinates are copied FROM the first selection TO the
second selection. If the selections overlap, watch out!. The matching is
done by number within the selected coordinate sets. If the two selection
have a different number of atoms, a warning will be issued, and the smaller
number will be used. For example, if one needs to compute the relative
orientation between two alpha helicies, the following input might be used;

COOR COPY COMP
COOR DUPL COMP SELE backbone of first END SELE backbone of second END
COOR ORIE RMS MASS COMP SELE backbone of second END

This will give the RMS shift between these helicies as well as the
coordinate transformation required to map one into the other.
The PREVious option may be used with a single atom selection.
This assigns the coordinate position of selected atoms to the value
of the previous atom (by number). This has been used with the command;
COOR DUPLicate PREVious SELE TYPE H* END
to assign hydrogen atom positions to that of the associated heavy atom.
The COMP keyword causes only the comparison coordinates to be used and
modified. Otherwise, the entire operation involves only the main coordinates.


Moderated by  lennart, rmv 

Link Copied to Clipboard
Powered by UBB.threads™ PHP Forum Software 7.7.5
(Release build 20201027)
Responsive Width:

PHP: 7.3.31-1~deb10u1 Page Time: 0.009s Queries: 26 (0.005s) Memory: 0.7580 MB (Peak: 0.8205 MB) Data Comp: Off Server Time: 2022-11-27 15:00:05 UTC
Valid HTML 5 and Valid CSS