Topic Options
#509 - 11/15/03 11:41 AM Mut2Ala.inp
jb007 Offline
Forum Member

Registered: 09/30/03
Posts: 250
Loc: Florida State
The script called "Alanine-scanning.inp" lacks an important part. Guess I got somewhat carried away (jetlagged) when posting it and the corrected input file is labelled Mut2Ala.inp

Please remove "Alanine-scanning.inp" from this list.

TIA

Johan

Top
#510 - 11/15/03 12:02 PM Re: Mut2Ala.inp [Re: jb007]
jb007 Offline
Forum Member

Registered: 09/30/03
Posts: 250
Loc: Florida State
*A system with "k" residues and
*"n" coordinate frames generated by MD
*Mutate residue "i" to alanine (or whatever)
*Generate mutant psf and trajectories.
*Rebuild missing atoms and recenter the coordinate frame.
*Write a modified trajectory in binary format.
*Trajectories in this example from simulations on the
*Glucocorticoid receptor DNA-Binding Domain
*Int. J. Quant Chem., 2001, 83, 230-
*PROTEINS, 2002, 49, 24-
*Johan Bredenberg 2003
nobo
read rtf card name $CHM_HOME/toppar/top_all22_prot.inp
read para card name $CHM_HOME/toppar/par_all22_prot.inp

!Declare wild-type psf

read sequ card
*title: 1-seq. amino_acids in GR
*monomer + two zn ions
*
71
cyc leu val cyc ser asp glu ala ser gly -
cys hsp tyr gly val leu thr cyc gly ser -
cyc lys val phe phe lys arg ala val glu -
gly gln hsp asn tyr leu cyc ala gly arg -
asn asp cyc ile ile asp lys ile arg arg -
lys asn cyc pro ala cyc arg tyr arg lys -
cys leu gln ala gly met asn leu glu ala -
arg
generate dbd1 setup
read sequ zn 2
gene ion2 setup

scalar charge stat sele type ca end

!I use ca since they're always there.

!Alanine to ala is redundant.
!in this example all residues are included though.


set totres ?nsel
set k = 1


!read in the wild-type trajectory

open unit 34 read unform name tmp.trj
trajec query unit 34
set n ?nfile
trajec firstu 34 nuni 1 begin

set p = 1
!counter for extracting the coordinates

label dumpcoord
trajec read
coor stat
coor orie norot
coor stat

!dump cartesian coordinates
write coor card name @p.crd

incr p by 1
if p le @n goto dumpcoord

!remove everything

dele atom sele all end



label INIT
! re-initiate coordinate frame reading
set p = 1

!residue seq number to be transformed into ala
set i @k

!*MUTATION OF RESIDUE I TO ALANINE
!*SAFE APPROACH
!*
SET 1 = CYC
SET 2 = LEU
SET 3 = VAL
SET 4 = CYC
SET 5 = SER
SET 6 = ASP
SET 7 = GLU
SET 8 = ALA
SET 9 = SER
SET 10 = GLY
SET 11 = CYS
SET 12 = HSP
SET 13 = TYR
SET 14 = GLY
SET 15 = VAL
SET 16 = LEU
SET 17 = THR
SET 18 = CYC
SET 19 = GLY
SET 20 = SER
SET 21 = CYC
SET 22 = LYS
SET 23 = VAL
SET 24 = PHE
SET 25 = PHE
SET 26 = LYS
SET 27 = ARG
SET 28 = ALA
SET 29 = VAL
SET 30 = GLU
SET 31 = GLY
SET 32 = GLN
SET 33 = HSP
SET 34 = ASN
SET 35 = TYR
SET 36 = LEU
SET 37 = CYC
SET 38 = ALA
SET 39 = GLY
SET 40 = ARG
SET 41 = ASN
SET 42 = ASP
SET 43 = CYC
SET 44 = ILE
SET 45 = ILE
SET 46 = ASP
SET 47 = LYS
SET 48 = ILE
SET 49 = ARG
SET 50 = ARG
SET 51 = LYS
SET 52 = ASN
SET 53 = CYC
SET 54 = PRO
SET 55 = ALA
SET 56 = CYC
SET 57 = ARG
SET 58 = TYR
SET 59 = ARG
SET 60 = LYS
SET 61 = CYS
SET 62 = LEU
SET 63 = GLN
SET 64 = ALA
SET 65 = GLY
SET 66 = MET
SET 67 = ASN
SET 68 = LEU
SET 69 = GLU
SET 70 = ALA
SET 71 = ARG

!mutate residue number "i" to alanine
set @i = ala

!Make a mutant psf

read sequ card
*AMINO-ACIDS
*
71
@1 -
@2 -
@3 -
@4 -
@5 -
@6 -
@7 -
@8 -
@9 -
@10 -
@11 -
@12 -
@13 -
@14 -
@15 -
@16 -
@17 -
@18 -
@19 -
@20 -
@21 -
@22 -
@23 -
@24 -
@25 -
@26 -
@27 -
@28 -
@29 -
@30 -
@31 -
@32 -
@33 -
@34 -
@35 -
@36 -
@37 -
@38 -
@39 -
@40 -
@41 -
@42 -
@43 -
@44 -
@45 -
@46 -
@47 -
@48 -
@49 -
@50 -
@51 -
@52 -
@53 -
@54 -
@55 -
@56 -
@57 -
@58 -
@59 -
@60 -
@61 -
@62 -
@63 -
@64 -
@65 -
@66 -
@67 -
@68 -
@69 -
@70 -
@71
gene mut setup
read sequ zn 2
gene iom setup

write psf card name @k.psf


!write a modified trajectory for
!the k:th mutation for a total of i residues

open unit 35 write unform name @k.trj
trajec iwrite 35 nfile @n begin 1

label readc
read coor card name @p.crd
!coordinate frame
ic para
ic build

!add carbon-beta-hydrogens (for Ala)
hbuild sele ( type hb* .and. ( segid mut .and. ( resid @i ) ) )
!add missing beta-hydrogen(s)
end
coor stat
coor orie mass
coor stat
trajec write
incr p by 1
if p le @n goto readc
rewind unit 34
close unit 35

!mutate next residue in sequence - or whatever -
!remove the temporary mutated psf

dele atom sele all end

incr k by 1
if k le @totres goto INIT

stop

!At this stage, the modified trajectories can be
!used for subsequent calculations.

Top
#511 - 10/19/04 10:27 AM Re: Mut2Ala.inp [Re: jb007]
chuan Offline
Forum Member

Registered: 05/17/04
Posts: 222
This might be what i m looking for.
what is meant by "trajectory is modified"? i.e. how is it modified?

Top
#512 - 10/19/04 04:23 PM Re: Mut2Ala.inp [Re: chuan]
jb007 Offline
Forum Member

Registered: 09/30/03
Posts: 250
Loc: Florida State
I see,
well, modified in this case means that the chunks of coordinates stored in binary format are translated into human-readable , and then modified and then rewritten in binary format. *

The "modification" in this case is a truncation at the beta-carbon of the sidechain plus the addition of a hydrogen atom at the truncated site.

* it'd great if this could be done without the intermediate coordinate-handling , but I'm not aware of how this can be done

Top
#513 - 09/26/05 09:59 AM Re: Mut2Ala.inp [Re: jb007]
Sonya Offline
Forum Member

Registered: 09/26/05
Posts: 2
That's exactly what I'm looking for, thank you!
Could you help me, how to calculate the energy of the system during the new trajectory with modifyed residue?

Thank you

Top
#514 - 10/06/05 01:00 PM Re: Mut2Ala.inp [Re: Sonya]
jb007 Offline
Forum Member

Registered: 09/30/03
Posts: 250
Loc: Florida State
What do you mean by "energy" and what is it that you are trying to do?

Top

Moderator:  chmgr, John Legato, petrella