Topic Options
#329 - 10/23/03 06:34 AM noe-dynamics.inp
lennart Online   content

Forum Member

Registered: 09/25/03
Posts: 4741
Loc: ~ 59N, 15E
*FILENAME: noe-dynamics.inp
*PURPOSE: very basic MD example of DNA with NOE-like restraints on ends
*CAUTION: nucleic acid simulations in general don't work well in vacuum
*AUTHOR: Lennart Nilsson, Karolinska Institutet, October 2003
*
! take psf and coordinates that were generated with gen-dna.inp
! Unix environment variable CHM_HOME has to point to CHARMM installation directory
!REFERENCE:
!Nilsson, L., Clore, G. M., Gronenborn, A. M., Brunger, A. T., and Karplus, M. (1986).
! Structure Refinement of Oligonucleotides by Molecular-Dynamics with
! Nuclear Overhauser Effect Interproton Distance Restraints - Application to
! 5' D(C-G-T-a-C-G)2. Journal of Molecular Biology 188, 455-475.

! Get definitions of nucleotides acids and standard parameters
read rtf card name $CHM_HOME/toppar/top_all27_na.rtf
read param card name $CHM_HOME/toppar/par_all27_na.prm

! Get psf and coordinates
read psf card name atcg.psf
read coor card name atcg1.crd

! set up noe-like restraints on watson-crick hydrogen bonds of terminal base pairs
! useful to keep ends from frying if you study a DNA fragment taken out of a longer
! piece

! setup the restraints (cons.doc, section noe)
! this is not saved in the psf and has to be setup in each job
NOE
! basically harmonic restraint with force constant 4.0 kcal/mol/A**2
! A-T pair at one end
assign kmin 4.0 kmax 4.0 rmin 1.9 rmax 1.9 sele atom a 1 n1 end -
sele atom b 4 h3 end
assign kmin 4.0 kmax 4.0 rmin 1.9 rmax 1.9 sele atom a 1 h62 end -
sele atom b 4 o4 end
! G-C pair at the other
assign kmin 4.0 kmax 4.0 rmin 1.9 rmax 1.9 sele atom a 4 h22 end -
sele atom b 1 o2 end
assign kmin 4.0 kmax 4.0 rmin 1.9 rmax 1.9 sele atom a 4 h1 end -
sele atom b 1 n3 end
assign kmin 4.0 kmax 4.0 rmin 1.9 rmax 1.9 sele atom a 4 o6 end -
sele atom b 1 h41 end
! see what we have
print
print anal
! and only those that are in "serious" violation
print anal cut 0.05
! restraint set may be saved and later read again for analysis
END

open unit 12 write form name atcg-noe-0.res
open unit 21 write unform name atcg-noe-0.cor
open unit 22 write form name atcg-noe-0.mon
shake bonh param ! apply SHAKE on all bonds X-H
! heat from 48 K to 298 K in 10K increments every 500 steps
! then check temperature every 2000 steps to see that it is 298K +/-5K
! write out coordinates to trajectory every 100 steps
! save restart file at end
dynamics start time 0.002 nstep 10000 -
firstt 48.0 finalt 298.0 teminc 10.0 ihtfrq 500 -
ieqfrq 2000 ichecw 1 twindl -5.0 twindh +5.0 iasors 0 -
nprint 100 iprfrq 500 -
atom cdie fshift vshift cutnb 14.0 ctofnb 12.0 -
inbfrq -1 ihbfrq 0 - ! -1 for inbfrq/imgfrq means heuristic update
iunwrit 12 iuncrd 21 kunit 22 nsavc 100 !ie update nonbond list when any atom has moved
! > 0.5 * (CUTNB-CTOFNB) since last update
write coor card name atcg-noe.crd
* atcg coordinates after dynamics in vacuum, with noe restraints on ends
*
_________________________
Lennart Nilsson
Karolinska Institutet
Stockholm, Sweden

Top
#330 - 01/14/04 05:39 AM Re: noe-dynamics.inp [Re: lennart]
temuchin Offline
Forum Member

Registered: 11/13/03
Posts: 68
hi,
you say that nucleic acid simulations don't work well in vacuum.
can you refer me to an explanation?
what if i am just minimizing?
thanks.
t.

Top
#331 - 01/14/04 10:41 AM Re: noe-dynamics.inp [Re: temuchin]
lennart Online   content

Forum Member

Registered: 09/25/03
Posts: 4741
Loc: ~ 59N, 15E
MD simulation of a highly charged system such as DNA in vacuum usually produces ratther strange looking structures. A gentle minimization is probably OK.
_________________________
Lennart Nilsson
Karolinska Institutet
Stockholm, Sweden

Top

Moderator:  chmgr, John Legato, petrella