Topic Options
#326 - 10/23/03 06:33 AM minimize.inp
lennart Online   content

Forum Member

Registered: 09/25/03
Posts: 4741
Loc: ~ 59N, 15E
*FILENAME: minimize.inp
*PURPOSE: minimize protein with xtal waters in vacuum
*AUTHOR: Lennart Nilsson, Karolinska Institutet, October 2003
*
! use harmonic constraints to make minimization gradual
! take psf and coordinates that were generated with gen-prot.inp
! Unix environment variable CHM_HOME has to point to CHARMM installation directory

! Get definitions of amino acids and standard parameters
read rtf card name $CHM_HOME/toppar/top_all22_prot.inp
read param card name $CHM_HOME/toppar/par_all22_prot.inp

! Get psf and coordinates
read psf card name 4pti.psf
read coor card name 4pti.crd

! Save coordinates also in comparsion coordinate set for later use
coor copy comp

! Harmonic constraints on all protein atoms
cons harm force 20.0 sele segid bpti end

! First used Steepest Descent (a gentle minimizer)
minimize sd nstep 50 cdie eps 1.0 fshift vshift cutnb 13.0 ctofnb 12.0

! How different is the structure now?
coor orie rms sele segid bpti end
! And if we look at the waters instead?
coor orie rms sele segid xwat end

! Reduce harmonic constraints and minimize some more
cons harm force 10.0 sele segid bpti end
minimize abnr nstep 50
coor orie rms sele segid bpti end
! turn off harmonic constraints
cons harm force 0.0 sele segid bpti end
! then small constraints on backbone only
cons harm force 5.0 sele segid bpti .and. -
(type C .or. type N .or. type CA .or. type O) end
minimize abnr nstep 50
coor orie rms sele segid bpti end
cons harm force 0.0 sele segid bpti end
minimize abnr nstep 100
coor orie rms sele segid bpti end

write coor card name 4pti_min.crd
* 4pti coordinates after some minimization
* rmsd from xtal: ?rms
* total energy: ?ener
*
_________________________
Lennart Nilsson
Karolinska Institutet
Stockholm, Sweden

Top
#327 - 03/30/05 09:24 PM Re: minimize.inp, GBMV segmentation fault [Re: lennart]
Leonardo Offline
Forum Member

Registered: 03/17/05
Posts: 42
Loc: Chile-Santiago
Hello Lennart

First at all thanks for posting your scripts, them have been useful to me to learn. I try to modify your minimize script to perform a minimization of a protein without waters or ligands with a implicit solvent model, namely GBMV. As writen in gbmv.doc, I only add a GBMV setup before the minimizations in your script. it looks like this:

*FILENAME: minimize.inp
*PURPOSE: minimize protein with xtal waters in vacuum
*AUTHOR: Lennart Nilsson, Karolinska Institutet, October 2003
*
! use harmonic constraints to make minimization gradual
! take psf and coordinates that were generated with gen-prot.inp
! Unix environment variable CHM_HOME has to point to CHARMM installation directory

! Get definitions of amino acids and standard parameters
read rtf card name $CHM_GNU_HOME/toppar/top_all22_prot.inp
read param card name $CHM_GNU_HOME/toppar/par_all22_prot.inp

! Get psf and coordinates
read psf card name "1YPC.psf"
read coor card name "1YPC.crd"

! Save coordinates also in comparsion coordinate set for later use
coor copy comp

! Harmonic constraints on all protein atoms
cons harm force 20.0 sele segid PROT end

! define gbmv parameters !NEW
gbmv beta -20 epsilon 80 dn 1.0 watr 1.4 geom weight - !NEW
tol 1e-8 bufr 0.5 mem 10 cuta 20 hsx1 -0.125 hsx2 0.25 - !NEW
alfrq 1 emp 1.5 p3 0.70 p4 0.0 p6 8.0 onx 1.9 offx 2.1 - !NEW
wtyp 2 nphi 38 corr 1 shift -0.102 slope 0.9085 !NEW


! First used Steepest Descent (a gentle minimizer)
minimize sd nstep 100 -
cdie eps 1.0 switch vswitch cutnb 15.0 ctofnb 14.0 !DiFFERENT

! How different is the structure now?
coor orie rms sele segid PROT end !RMSD

! Reduce harmonic constraints and minimize some more
cons harm force 10.0 sele segid PROT end
minimize abnr nstep 100
coor orie rms sele segid PROT end !RMSD

! turn off harmonic constraints
cons harm force 0.0 sele segid PROT end

! then small constraints on backbone only
cons harm force 5.0 sele segid PROT .and. -
(type C .or. type N .or. type CA .or. type O) end
minimize abnr nstep 100
coor orie rms sele segid PROT end !RMSD

! minimization without any constraints
cons harm force 0.0 sele segid PROT end
minimize abnr nstep 1000
coor orie rms sele segid PROT end !RMSD

write coor card name "1YPC_min.crd"
* 1YPC coordinates after some minimization
* rmsd from xtal: ?rms
* total energy: ?ener


The only diference beetween your script and this is the 5 lines of the GBMV setup, and the Nonbond setup for the minimization, which changed the cuttoff function to switch as suggested in gbmv.doc. (well, I increased the number of steps of minimization too, but that doesnt cause problems)
This same script, without the 5 GBMV lines works well. Nevertheless, the addition of the GBMV setup creates a "segmentation fault" error in the comand line. The "output" file stops just after the first cons command:


CHARMM> ! Harmonic constraints on all protein atoms
CHARMM> cons harm force 20.0 sele segid PROT end
SELRPN> 1052 atoms have been selected out of 1052
CSTRAN: Harmonic Restraints
ABSOlute type as set number 1

I searched in the list about the "segmentation fault"; in most of them the signal is written to the output file, but in this case the segmentation fault error goes to the command line. Maybe this mean the problem is with my machine. The problem occurs with a charmm executable compiled with g77 and medium size and with other compiled with pgif77 and xxlarge size. Mi charmm version is c31b1 and my machine is an Intel Pentium 4 CPU 3.00GHz hyperthreading 512 kb cache and 1GB RAM. My linux version is Fedora Core 2.

Thanks in advance and Greetings from Chile

leonardo

Top
#328 - 04/04/05 12:20 AM Re: minimize.inp, GBMV segmentation fault [Re: Leonardo]
Leonardo Offline
Forum Member

Registered: 03/17/05
Posts: 42
Loc: Chile-Santiago
I think I found the problem: I used the WEIGHT comand to use the WMAIN array of radii. I seems this overloaded the memory, as sugested by a VEHEAP signal in the second output:

OUTPUT OF GBMV SETUP WITHOUT WEIGHT, NO PROBLEM

CHARMM> GBMV BETA -20 EPSILON 80 DN 1.0 watr 1.4 GEOM -
CHARMM> TOL 1e-8 BUFR 0.5 Mem 10 CUTA 20 HSX1 -0.125 HSX2 0.25 -
CHARMM> ALFRQ 1 EMP 1.5 P4 0.0 P6 8.0 P3 0.70 ONX 1.9 OFFX 2.1 -
CHARMM> SON 0.5 SOFF 1.75 -
CHARMM> WTYP 2 NPHI 38 CORR 1 SA 0.00592 SB 0.0
CHARMM> SHIFT -0.102 SLOPE 0.9085

Geometric Cross-Term
SASA term requested with
SA = 0.00592 kcal/(mol*A**2) and SB = 0.00000 kcal/mol.
Using EMP method with value of 1.5000
Running Analytical GBMV: Method II (VSA)
CFA Correction factor: (1/R^7)^(1/4)
Slope = 0.90850 Shift = -0.10200
P1 = 0.45000 P2 = 1.25000 P3 = 0.70000 P4 = 0.00000
P5 = 0.16000 P6 = 8.00000
Lambda = 0.50000 Beta = -20.00
CutA = 20.00000 Bufr = 0.50000 DN = 1.00000 Mem = 10
ALFRQ = 1 EMP = 1.50000 KAPPA = 0.00000
WProbe = 1.40000 EPS_GB= 80.00000
Hard sphere function from -0.125 to 0.250
Tail function switched from 1.900 to 2.100
Lebedev integration grid of size 38
Number of integration points = 798
Grid Extents: 48 X 49 X 35
Table Size = 3.14 MB
Surf. Pts = 0.84 MB
Grid Size = 1.32 MB

------------------------------------------------------------------------

OUTPUT OF GBMV SETUP WITH WEIGHT, CAUSES SEGMENTATION FAULT

CHARMM> ! Define gbmv parameters
CHARMM> gbmv beta -20 epsilon 80 dn 1.0 watr 1.4 geom WEIGHT -
CHARMM> tol 1e-8 bufr 0.5 mem 10 cuta 20 -
CHARMM> hsx1 -0.125 hsx2 0.25 onx 1.9 offx 2.1 -
CHARMM> alfrq 1 emp 1.5 son 0.5 soff 1.75 -
CHARMM> p1 0.45 p2 1.25 p3 0.70 p4 0.0 p5 0.16 p6 8.0 -
CHARMM> sa 0.00592 sb 0.0 kappa 0.0 wtyp 2 nphi 38 -
CHARMM> corr 1 shift -0.102 slope 0.9085
Geometric Cross-Term
SASA term requested with
SA = 0.00592 kcal/(mol*A**2) and SB = 0.00000 kcal/mol.
Using EMP method with value of 1.5000
Running Analytical GBMV: Method II (VSA)
CFA Correction factor: (1/R^7)^(1/4)
Slope = 0.90850 Shift = -0.10200
P1 = 0.45000 P2 = 1.25000 P3 = 0.70000 P4 = 0.00000
P5 = 0.16000 P6 = 8.00000
Lambda = 0.50000 Beta = -20.00
CutA = 20.00000 Bufr = 0.50000 DN = 1.00000 Mem = 10
ALFRQ = 1 EMP = 1.50000 KAPPA = 0.00000
WProbe = 1.40000 EPS_GB= 80.00000
Hard sphere function from -0.125 to 0.250
Tail function switched from 1.900 to 2.100
Lebedev integration grid of size 38
Number of integration points = 798
Using Radii from WMAIN array
Grid Extents: 100 X 101 X 88
Table Size = 53.21 MB
Surf. Pts = 0.84 MB
Grid Size = 14.22 MB
VEHEAP> Expanding heap size by10649600 words.
...the error comes a few lines later

Note the difference in the table and grid size. Taking out WEIGHT from the second setup fix the problem, so I guess that was all. I wrote that command because in the GBSW module the use of a suitable vdw radii was stressed, and I thougth it may be usefull to GBMV too. A very bad idea. Nevertheless I dont know why this happens. ¿Someone can give some advice about it?

Thanks

Leonardo
_________________________
Leonardo Sepulveda Durán Universidad de Chile

Top

Moderator:  chmgr, John Legato, petrella