Page 1 of 4 1 2 3 4 >
Topic Options
#293 - 10/23/03 06:30 AM interaction-energy.inp
lennart Online   content

Forum Member

Registered: 09/25/03
Posts: 4741
Loc: ~ 59N, 15E
*FILENAME: interaction-energy.inp
*PURPOSE: compute interaction energies from trajectory
*AUTHOR: Lennart Nilsson, Karolinska Institutet, October 2003
*
!unix environment variable CHM_HOME points to CHARMM installation directory
read rtf card name $CHM_HOME/toppar/top_all22_prot.inp
read para card name $CHM_HOME/toppar/par_all22_prot.inp
read psf card name my_psf.psf

open unit 51 read unform name my_traj1.cor
open unit 52 read unform name my_traj2.cor
! specify how we are going to read the trajectory
traj firstu 51 nunit 2 skip 2500 ! use whole trajectory, pick frames every 5 ps

open write unit 21 form name inter_1_2.dat
write title unit 21
* time res1-res2 prot-ligand
*
set t 0.0 ! keep track of time, assume traj is from 0 to 750 ps

label loop
! get next coordinate set according to specifications above
traj read
! we have to update lists every time, things can move a lot in 5ps
update cutnb 12.0 ctofnb 12.0 fshift vshift cdie
! first get interaction energy between residues 1 and 2 in the protein
inte sele segid prot .and. resi 1 end sele segid prot .and. resi 2 end
! ?ener is total energy. other terms may also be extracted,
! see energy.doc, section Substitution, for more details
set e1 ?ener
! and protein ligand interaction
inte sele segid prot end sele segid lig end
set e2 ?ener
write title unit 21
* @t @e1 @e2
*

incr t by 5.0
if t lt 750.0 goto loop
_________________________
Lennart Nilsson
Karolinska Institutet
Stockholm, Sweden

Top
#294 - 11/10/04 11:30 AM Re: interaction-energy.inp [Re: lennart]
noskov Offline
Forum Member

Registered: 06/18/04
Posts: 162
Loc: Calgary, AB
Lennart,

Why you use a cut-offs while computing interaction energies from simulation. I realize that it is impossible to use a long-range corrections for an interactions, but should it be a cutnb of 999, for example? and why shift but not switch? Any specific reason?
_________________________
Sergei Noskov snoskov@ucalgary.ca Dept.BioSciences University of Calgary

Top
#295 - 11/10/04 12:41 PM Re: interaction-energy.inp [Re: noskov]
lennart Online   content

Forum Member

Registered: 09/25/03
Posts: 4741
Loc: ~ 59N, 15E
I normally use the same options for the interaction energy as I used during the simulation, so that the result is the same as would have been obtained if these terms had been saved during the simulation. It is of course possible to use something different, but why complicate things - remember that you will have to write an understandable methods section at some point...
One can turn the argument around:
If you find an important interaction by using an infinite cutoff in the interaction energy calculation, then why was this not important enough to have been included in the first place?
_________________________
Lennart Nilsson
Karolinska Institutet
Stockholm, Sweden

Top
#296 - 11/10/04 02:12 PM Re: interaction-energy.inp [Re: noskov]
jb007 Offline
Forum Member

Registered: 09/30/03
Posts: 250
Loc: Florida State
I strongly agree on using the same interaction potential as was used during the simulation , at least for the non-"covalent " force-field terms while , for instance, the popular approach to post-process the solvent effects with a continuum approximation, may be better of using an "infinite" cutoff.

Top
#297 - 11/10/04 02:29 PM Re: interaction-energy.inp [Re: lennart]
noskov Offline
Forum Member

Registered: 06/18/04
Posts: 162
Loc: Calgary, AB
It make sence if you want to estimate site-site or let's say amino-acid - amino-acid interactions, but... for post-processing such as computation of receptor-ligand(molecule-molecule) interaction the inclusion of all atoms in the system may even change the sign of total non-bonded interactions for higly charged species.(it is the case jb007 mentioned above as an example, post-processing with some continuum electrostatic methods).

Thanks a lot for your reply.


Edited by noskov (11/10/04 02:30 PM)
_________________________
Sergei Noskov snoskov@ucalgary.ca Dept.BioSciences University of Calgary

Top
#298 - 04/06/05 11:45 AM Re: interaction-energy.inp [Re: lennart]
Shirley Offline
Forum Member

Registered: 07/13/04
Posts: 56
Dear CHARMMERs,

I was using the script lennart provided here to calculate the interaction energy between two portions of the system. I wonder how "750 ps" used here comes out. Say my trajectory includes trj24..trj30, and each trajectory contains 50 ps. In this case, should I make changes to this script as follows:

========================
set t 1200.0
...
incr t by 5.0
if t lt 1500.0 goto loop
=======================

However, when I used something else such as 3000.00 instead of 1500.0 here in the IF..loop command, the calculation still continued after the 1500.0 ps, and gave non-zero interaction energy values.

I'm little confused here, could someone provide some helpful comments?

Thank you very much.

Shirley

Top
#299 - 04/06/05 12:10 PM Re: interaction-energy.inp [Re: Shirley]
rmv Online   content

Forum Member

Registered: 09/17/03
Posts: 8373
Loc: 39 03 48 N, 77 06 54 W
You have 7 files, so the time interval is 350 ps, not 300.

Top
#300 - 04/06/05 12:32 PM Re: interaction-energy.inp [Re: rmv]
Shirley Offline
Forum Member

Registered: 07/13/04
Posts: 56
Thank Rick very much for the helpful comment.

So, for traj 24..30, which of the following settings should I use?

========= 1 ===============
set t 1200.0 !! 1200 = 24*50
...
incr t by 5.0
if t lt 1500.0 goto loop !! 1500 = 30 * 50
=======================

========== 2 ==============
set t 0.0
...
incr t by 5.0
if t lt 350.0 goto loop
=======================

Thank you again for your kind help.

Shirley

Top
#301 - 04/06/05 01:10 PM Re: interaction-energy.inp [Re: Shirley]
rmv Online   content

Forum Member

Registered: 09/17/03
Posts: 8373
Loc: 39 03 48 N, 77 06 54 W
Neither-- dyn24.trj ends with the 1200 ps point, but the first time point in that file should be 1151 ps.

Top
#302 - 04/08/05 12:54 PM Re: interaction-energy.inp (about the upper limit of time points) [Re: rmv]
Shirley Offline
Forum Member

Registered: 07/13/04
Posts: 56
Thank you for your help, Rich.

I wanted to see what would happen if I assign the last maximum time point a value exceeding the real maximum, so I did two test runs for traj24-25 which includes a total interval of 100 ps covering the time points of 1151-1250 ps. The following settings were used for the two runs respectively:

======= param for run1 =================
set tmax 1250.0 !! This value will be diff. in run2
set t 1151.0
...
incr t by 5.0
if t lt @tmax goto loop
...
=== end of param for run1 ===============

======= param for run2 =================
set tmax 1500.0 !! NOTE the diff. from the value in run1

set t 1151.0
...
incr t by 5.0
if t lt @tmax goto loop
...
=== end of param for run2 ===============

What I expect from these tests is that test 2 should give an error, since the assigned value for @tmax exceeds the maximum available trajectory time points, or at most it gives the same amount of time-energy output. However as a matter of fact, test 2 gives the output for time points from 1151.0 ps all the way to 1446.0 ps with total time interval of 300 ps. I wonder how the output for the last 200 ps was generated.

I guess there must be something wrong in my input, or I didn't understand the scheme correctly. Could you give some suggestions?

Thank you very much.

Regards,

Shirley

Top
#303 - 04/08/05 01:14 PM Re: interaction-energy.inp (about the upper limit of time points) [Re: Shirley]
rmv Online   content

Forum Member

Registered: 09/17/03
Posts: 8373
Loc: 39 03 48 N, 77 06 54 W
If your data is stored at 1.0 ps intervals (e.g. NSAVC 1000 for 1 fs timestep), changing the increment of the loop counter won't affect that, and the resulting time data would be incorrect. You'd also have to change the SKIP value when for the initial TRAJ command which sets up the trajectory reading, e.g. change it SKIP 5000 to extract points at a 5 ps interval instead of the 1 ps interval used when the file was generated.

Top
#304 - 04/18/05 05:54 PM Thank you [Re: rmv]
Shirley Offline
Forum Member

Registered: 07/13/04
Posts: 56
Thank Rick so much for the helpful instruction and example. Now I'm clear. I didn't specify an appropriate value for SKIP before, and therefore I didn't get the results right.

Thanks a lot.

Shirley

Top
#305 - 05/18/06 05:31 PM Re: interaction-energy.inp [Re: lennart]
nnn Offline
Forum Member

Registered: 11/15/05
Posts: 51
Hi,

I would like to calculate the interaction between metal and ligand over the simulation. I have modified my script like this:
! Read in trajectories

open unit 51 read unform name "../../../6-prod/mgsys.dcd"

traj firstu 51 nunit 1 skip 5000

open write unit 21 form name inter_mg_cit.dat
write title unit 21
* time mg-ligand
*
set t 0.0 ! keep track of time, assume traj is from 0 to 750 ps

label loop
! get next coordinate set according to specifications above
traj read
! we have to update lists every time, things can move a lot in 5ps
update cutnb 12.0 ctofnb 11.0 ctonnb 8.0 -
atom fswitch cdie vdw vshift

! ?ener is total energy. other terms may also be extracted,
! see energy.doc, section Substitution, for more details
set e1 ?ener
! and protein ligand interaction
inte sele atom MMAT 154 MG end -
sele atom QMAT 155 N2 -
.or. atom QMAT 155 N1 -
.or. atom QMAT 155 N4 -
.or. atom QMAT 155 N3 -
.or. atom QMAT 155 C1 -
.or. atom QMAT 155 C2 -
.or. atom QMAT 155 O1 -
.or. atom QMAT 155 C3 -
.or. atom QMAT 155 H1 -
.or. atom QMAT 155 C12 -
.or. atom QMAT 155 O2 -
.or. atom QMAT 155 C10 -
.or. atom QMAT 155 C7 -
.or. atom QMAT 155 C6 -
.or. atom QMAT 155 H3 -
.or. atom QMAT 155 C5 -
.or. atom QMAT 155 CL1 -
.or. atom QMAT 155 C4 -
.or. atom QMAT 155 H2 -
.or. atom QMAT 155 C9 -
.or. atom QMAT 155 H4 -
.or. atom QMAT 155 C8 -
.or. atom QMAT 155 N5 -
.or. atom QMAT 155 H6 -
.or. atom QMAT 155 C11 -
.or. atom QMAT 155 H5 end

set e2 ?ener
write title unit 21
* @t @e1 @e2
*

incr t by 5.0
if t lt 1000.0 goto loop

stop

and my xxx.dat looks like this:

TIME MG-LIGAND
0.0 0 15.8467
5 15.8467 12.8259
10 12.8259 13.7943
15 13.7943 20.5529
20 20.5529 17.4542
25 17.4542 19.2578
30 19.2578 19.0469
35 19.0469 15.0701

In this case, I dont have interaction between resid 1 and resid 2, like in the example script. So which column (1 or 2), I could use?

Moreover, I got the positive value of energies (I suppose it must be negative). Is there something wrong with the script? Any suggestion is appreciated. Thanks in advance.

Top
#306 - 05/18/06 06:20 PM Re: interaction-energy.inp [Re: nnn]
rmv Online   content

Forum Member

Registered: 09/17/03
Posts: 8373
Loc: 39 03 48 N, 77 06 54 W
The example script has two INTE commands, yours has only one; that's why your values are repeated (the 1st energy value on each line is the same as the second on the previous line) and the first line has zero as the first energy. In this case you could simplify by having

write title unit 21
* @t ?ENER
*


and dropping the 'set e1' and 'set e2' commands. You only need one column of data in this case.

I don't think you should assume that INTE should be negative.
_________________________
Rick Venable
computational chemist


Top
#307 - 05/18/06 06:52 PM Re: interaction-energy.inp [Re: rmv]
nnn Offline
Forum Member

Registered: 11/15/05
Posts: 51
Thank Prof. Rick.

Now I have one column for interaction energy.
In this case, the positive values of interaction energies means that ligand does not like to interact or form complex with metal indicating unstable system, is that right? First I assume that my ligand would strongly interact with metal ion. Any comment is very useful. Thanks.

Top
#308 - 05/18/06 07:44 PM Re: interaction-energy.inp [Re: nnn]
rmv Online   content

Forum Member

Registered: 09/17/03
Posts: 8373
Loc: 39 03 48 N, 77 06 54 W
The INTEraction energy is not necessarily highly correlated to the free energy of binding, and you may also have neglected additional interactions that may be important. Surely there are other atoms within a 5-10 A sphere around the metal besides that one ligand ...
_________________________
Rick Venable
computational chemist


Top
#309 - 08/01/06 11:26 PM Re: interaction-energy.inp [Re: lennart]
zoe Offline
Forum Member

Registered: 06/29/04
Posts: 31
Loc: New Haven, CT
Dear Prof.Nilsson,

If I want to compute the interaction energy including the images of my trajectory do i have to invoke the crystal environment to do this?

In this case, will the ?ener command give me the total interaction energy including the images' itneraction energy?

Best Regards,
Zoe

Top
#310 - 08/08/06 04:24 AM Re: interaction-energy.inp [Re: zoe]
lennart Online   content

Forum Member

Registered: 09/25/03
Posts: 4741
Loc: ~ 59N, 15E
The interaction energy command does not include image terms.
You could try to duplicate your system (GENE ... DUPL ..; COOR DUPL), apply COOR OPER commands to one of the copies and then do an interaction energy.
_________________________
Lennart Nilsson
Karolinska Institutet
Stockholm, Sweden

Top
#311 - 08/09/06 10:14 PM Re: interaction-energy.inp [Re: lennart]
cathy Offline
Forum Member

Registered: 02/01/05
Posts: 31
Dear Lennart,

thank you for providing the sript. it is very helpful. i am using it to calculate the interaction energies between protein and a series of ligands. i want to use these interaction energies as index of binding affinity of the ligands.

Could you please tell me how it works, namely what is the energy function of charmm INTE ENERGY command? i couldn't get a clear anwser from energy.doc where it is only indicated that terms such as bond,angle, dihedral, improper angle, van der waals, electrostatic, and hbond et al. are included in the function.

Many thanks in advance.

Cathy

Top
#312 - 08/10/06 02:37 AM Re: interaction-energy.inp [Re: cathy]
lennart Online   content

Forum Member

Registered: 09/25/03
Posts: 4741
Loc: ~ 59N, 15E
The command is "INTE" (not INTE ENERGY). The energy function is basically the standard CHARMM potential energy, with some restrictions as indicated in energy.doc, eg some two-body energy terms are only computed if the first atom is present in the first selection and the second atom is in the second selection. In your case (protein + non-covalently bonded ligand) there will only be van der Waals and Coulomb contributions. Did you see any other non-zero terms printed in the output?
_________________________
Lennart Nilsson
Karolinska Institutet
Stockholm, Sweden

Top
#313 - 08/10/06 12:41 PM Re: interaction-energy.inp [Re: cathy]
rmv Online   content

Forum Member

Registered: 09/17/03
Posts: 8373
Loc: 39 03 48 N, 77 06 54 W
Note that interaction energy is an estimate of the enthalpy, and would only correlate strongly to binding if the entropy term of the free energy is small or constant. Also, the "rule of thumb" has been that it's difficult to distinguish between cases where the binding constant difference is significantly smaller than 3 orders of magnitude.
_________________________
Rick Venable
computational chemist


Top
#314 - 09/04/06 11:08 AM Re: interaction-energy.inp [Re: lennart]
beginner Offline
Forum Member

Registered: 07/19/04
Posts: 165
Dear all,

I would like to examine the interaction energy between peptide residue and lipid bilayer, but as a function of distance from membrane center instead of time. Could you please guide me how to get that?

Thank you very much.

Top
#315 - 09/04/06 11:47 AM Re: interaction-energy.inp [Re: beginner]
lennart Online   content

Forum Member

Registered: 09/25/03
Posts: 4741
Loc: ~ 59N, 15E
Extract the distance you are interested in as well, and put that instead of the time (or as an extra column) in the output table. See eg COOR AXIS command (corman.doc).
_________________________
Lennart Nilsson
Karolinska Institutet
Stockholm, Sweden

Top
#316 - 01/20/09 05:38 AM Re: interaction-energy.inp [Re: lennart]
zee Offline
Forum Member

Registered: 07/05/04
Posts: 53
Hi there.
I'm trying to determine the interaction energy between two lipids in a lipid bilayer. How do I determine the starting point, i.e. how do I tell CHARMM where (in the TRJ) to start the reading? I tried with BEGIN and START, but it's not working. The trajectory was save with SKIP=1000, whereas I'm reading it with SKIP=10000. The trajectory covers 30 ns of simulation, but I would like to analyse only the last 20 ns.

My input is as follows:
* measure interaction energy

bomlev -2

! parameters needed
! only parts before PSF/COR/TRJ needed
! c - composition of membrane system
! r - residue CHL1/SM
! 1 - residue number, must be a CHL1
! 2 - name of segi 2

! name of main lipid segment
set 2 main

! Load parameters
open read unit 1 card name top_all27_lipid.rtf
read rtf card unit 1
clos unit 10

open read unit 1 card name par_all27_lipid.prm
read param card unit 1

stream toppar_all27_lipid_cholesterol.str

! Load coordinates
open read unit 1 card name sys8fixed.psf
read psf card unit 1
open read unit 1 card name dyn.cor
read coor card unit 1

!defi test sele resi @1 .and. segi main show end

!stop

!coor stat

!stop

crystal define tetragonal 95.0 95.0 59.5 90.0 90.0 90.0
crystal build cutoff 14.0

imag byres sele resnam TIP3 .or. resnam CHL1 .or. resn SM end

nbond atom vatom cutnb 14.0 ctofnb 10. cdie eps 1. -
ctonnb 7. vswitch cutim 14.0 imgfrq -1 wmin 1.0 -
ewald pmew fftx 128 ffty 128 fftz 72 kappa .33 spline order 6

ener

!stop

! Load trajectory
open read unit 11 file name dyn_c-05.0-35.0ns.trj
traj firstu 11 nunit 1 skip 10000 !begin 15001000

!stop

! Open output data file
! asterisks denote which interaction we are measuring
open write unit 99 form name inter-ener-mem@c-@r-@s-@1-@2.dat
write title unit 99
* time ep evdw el
*

set t 0.0 ! keep track of time, assume traj is from 0.0 till the end

label loop

traj read
! we have to update lists every time
! use the same parameters as during simulation!
upda atom vatom cutnb 14.0 ctofnb 10. cdie eps 1. -
ctonnb 7. vswitch cutim 14.0 imgfrq -1 wmin 1.0 -
ewald pmew fftx 128 ffty 128 fftz 72 kappa .33 spline order 6

inte sele (resi @1 .and. segi main) end sele .not. (resi @1 .and. segi main) end

! ?ener is total energy. other terms may also be extracted,
! see energy.doc, section Substitution, for more details
set ep ?ener
set evdw ?vdw
set el ?elec

write title unit 99
* @t @ep @evdw @el
*

incr t by 100.0
if t le 3500.0 goto loop

stop
stop

------
Thanks in advance,
zee


Edited by zee (01/20/09 05:40 AM)

Top
#317 - 01/20/09 05:53 AM Re: interaction-energy.inp [Re: zee]
lennart Online   content

Forum Member

Registered: 09/25/03
Posts: 4741
Loc: ~ 59N, 15E
Why do you need bomlev -2?
BEGIn is the correct keyword, so what was the problem you had ("not working" is a bit brief if you want help).
Interaction energies with pme are not particularly well-defined (pme is not really pairwise decomposable), and I don't think you need the images either for this kind of calculation. Your interaction_energy command does not calculate the interaction energy between two lipids.
Note that your OPEN READ and TRAJ FIRST commands do NOT load the trajectory (they do not transfer any data).
_________________________
Lennart Nilsson
Karolinska Institutet
Stockholm, Sweden

Top
#318 - 01/20/09 06:35 AM Re: interaction-energy.inp [Re: lennart]
zee Offline
Forum Member

Registered: 07/05/04
Posts: 53
Thank you for the prompt reply.
Bomlev is set to -2 for no particular reason, I set it to 0.

Since PME was used during simulation I think it is better to leave it on for the analysis part.

I apologize for not being clear enough. I calculate the interaction energy between a given lipid molecule and the rest of the system.

I uncommented the "begin 15010000" part and re-run the job. It doesn not fail, though it should since I set the value of "t" to 3600 which is outside the trajectory (total number of frames is 35001000). I attach the output file.

What confuses me is CHARMM not giving any indication of the BEGIn being set as it does for skip. Is this normal behaviour?

zee


Attachments
20124-output-test.txt (684 downloads)


Top
#319 - 01/20/09 06:57 AM Re: interaction-energy.inp [Re: zee]
lennart Online   content

Forum Member

Registered: 09/25/03
Posts: 4741
Loc: ~ 59N, 15E
I'd simply not have a bomlev command at all.
As you can see from your output there is no PME and no image energy from the interaction_energy command.
I must say that I fail to see the relevance of the value of your variable t.
Yes, the TRAJ command for some reason ("historical"?) does not print out any more information than what you see. You can change this if you want by adding code as needed in file source/io/trajio.src.
Your initial energy command gives a very large (0.20334E+19) vdW energy.
_________________________
Lennart Nilsson
Karolinska Institutet
Stockholm, Sweden

Top
#320 - 01/20/09 07:51 AM Re: interaction-energy.inp [Re: lennart]
zee Offline
Forum Member

Registered: 07/05/04
Posts: 53
Thanks for the advice on the bomlev.

I see there's no PME and no image energy for the interaction_energy but I fail to see why this happens. Though the energy.doc file suggests the values for energy will be zeroed but for the following terms:
Bond - Energy defined by the two atoms involved.
Angles - Energy allocated to the central atom (auto energy only).
Dihedral - Energy defined between central two atoms
Improper - Energy defined by first atom (auto energy only)
van der Waal - ATOM option only. Energy defined by two atoms involved.
Electrostatic - ATOM option only. Energy defined by two atoms involved.
Hbond - Energy defined by heavy atom donor and acceptor atom.
Harmonic cons - Energy allocated to central atom (auto energy only).
Dihedral cons - Energy defined by central two atoms.
User energy - Atom selections may be passed to USERE in the selection
common (DEFIne command). Fill forces and energies as desired.

Thank you for the information on the TRAJ command.

The initial energy command gives a large vdW energy because the initial (step 0) unit cell is not tall (along z axis) enough. This error is corrected in subsequent steps because the trajectory contains the crystal data from the simulation.

The variable "t" is just a measure of time and I use to step out of the "traj read" loop. I don't know else what could I use as a trigger/switch to exit the loop otherwise. Will CHARMM exit the loop when the end of the trajectory is reached if no other conditions are specified?

Thank you again.
zee

Top
#321 - 01/20/09 07:59 AM Re: interaction-energy.inp [Re: zee]
zee Offline
Forum Member

Registered: 07/05/04
Posts: 53
Minor addition. Upon adding the "ener" command in the loop I get:
NER ENR: Eval# ENERgy Delta-E GRMS
ENER INTERN: BONDs ANGLes UREY-b DIHEdrals IMPRopers
ENER EXTERN: VDWaals ELEC HBONds ASP USER
ENER IMAGES: IMNBvdw IMELec IMHBnd RXNField EXTElec
ENER EWALD: EWKSum EWSElf EWEXcl EWQCor EWUTil
---------- --------- --------- --------- --------- ---------
ENER> 0 -94460.30516 94407.04284 18.63891
ENER INTERN> 22555.96027 24860.01355 7553.39409 12340.67470 0.00000
ENER EXTERN> -3931.87294-114083.62288 0.00000 0.00000 0.00000
ENER IMAGES> -865.40355 -9797.38733 0.00000 0.00000 0.00000
ENER EWALD> 1773.42130-763869.88948 729004.40712 0.00000 0.00000
---------- --------- --------- --------- --------- ---------

So I think the script is working as expected.

Top
#322 - 01/20/09 08:09 AM Re: interaction-energy.inp [Re: zee]
lennart Online   content

Forum Member

Registered: 09/25/03
Posts: 4741
Loc: ~ 59N, 15E
The interaction_energy command simply does not compute the other energy terms, as clearly indicated in the documentation.

You are right in using a loop counter, but in order to interpret t=3600 as meaning 36 ns you have to specify t correctly. If your timestep during the simulation was 0.001 ps and you use SKIP 10000 then your t increment of 100 means the t=1 corresponds to 0.1ps, and t=3600 is 3.6 ns, not 36 ns. The initial t should also match the BEGIN value.
The CHARMM variable ?TIME contains the time into the trajectory (in ps) after each invocation of TRAJ READ.
CHARMM stops reading when it reaches end-of-file.
_________________________
Lennart Nilsson
Karolinska Institutet
Stockholm, Sweden

Top
#323 - 01/20/09 08:11 AM Re: interaction-energy.inp [Re: zee]
lennart Online   content

Forum Member

Registered: 09/25/03
Posts: 4741
Loc: ~ 59N, 15E
Well, the energy command calculates all the energy terms, but the INTEraction_energy command does not, if that is what you tried to check.
_________________________
Lennart Nilsson
Karolinska Institutet
Stockholm, Sweden

Top
#21833 - 08/25/09 02:00 PM Re: interaction-energy.inp [Re: lennart]
beginner Offline
Forum Member

Registered: 07/19/04
Posts: 165
sorry if this is very naive question.

The unit of energy term is kcal/mol.

In case, we calculated the interaction energy between different molecules with this script (i.e. peptide lipid interaction). The results will be kcal/mol of peptide or kcal/mol of lipid.

Thank you for your support.

Top
#21835 - 08/25/09 03:15 PM Re: interaction-energy.inp [Re: beginner]
lennart Online   content

Forum Member

Registered: 09/25/03
Posts: 4741
Loc: ~ 59N, 15E
kcal/(mol of your system); divide the printed value by Avogadro's number and you have the energy in kcal for exactly the system defined by your selections in the interaction energy command.
_________________________
Lennart Nilsson
Karolinska Institutet
Stockholm, Sweden

Top
#34486 - 10/13/14 09:24 AM Re: interaction-energy.inp [Re: lennart]
RobertoP Offline
Forum Member

Registered: 10/13/14
Posts: 10
Hi Lennart,
I'd like to calculate the energy of interaction between ligand/receptor. I used a .CRD file as input of your script but this error occured:

CHARMM> READ COORDINATES CARD FREE UNIT 13
SPATIAL COORDINATES BEING READ FROM UNIT 13

***** LEVEL 0 WARNING FROM *****
***** Cannot append to full set
******************************************
BOMLEV ( 0) IS REACHED - TERMINATING. WRNLEV IS 5

Is it possible to modify your script in order to use my .CRD as input?

Thanks in advance

RobertoP

Top
#34487 - 10/13/14 10:09 AM Re: interaction-energy.inp [Re: lennart]
lennart Online   content

Forum Member

Registered: 09/25/03
Posts: 4741
Loc: ~ 59N, 15E
Please show full input and output; it seems that you have not generated a PSF. The answer to your question is: Maybe. It depends on what is in your coordinate file.
_________________________
Lennart Nilsson
Karolinska Institutet
Stockholm, Sweden

Top
Page 1 of 4 1 2 3 4 >

Moderator:  chmgr, John Legato, petrella