Previous Thread
Next Thread
Print Thread
make RHDO via spherical cut from a box
#1195 04/03/04 10:34 PM
Joined: Sep 2003
Posts: 8,499
rmv Offline OP
Forum Member
OP Offline
Forum Member
Joined: Sep 2003
Posts: 8,499
* make 20 A radius sphere of water; precursor to RHDO w. a=36
* cut 1/8 sphere from a box, rotate 3 times to get a sphere
* convert sphere to RHDO by minimization
* volumes are equivalent; see crystl.doc for RHDO formula
*

! READ RTF AND PARAM FILES
open unit 1 read card name "~charmm/c30b1/toppar/top_all22_prot.inp"
read rtf card unit 1
close unit 1

open unit 1 read card name "~charmm/c30b1/toppar/par_all22_prot.inp"
read param card unit 1
close unit 1

! CREATE WATER SEGMENT FOR INITIAL BOX
read sequ tip3 1340
gener WAT noang nodihe
! READ COORDS FOR THE BOX
open unit 2 read card name "../../W34tst/box34.crd"
read coor card unit 2
close unit 2
! MOVE CORNER TO ORIGIN; NPT EQUILIBRATED BOX EDGE
set a 34.1995
calc a2 = 0.5 * @A
coor tran xdir @A2 ydir @A2 zdir @A2

! CUT A 1/8 SPHERICAL SECTION (+++ OCTANT)
define sph sele .byres. ( point 0. 0. 0. cut 20.0 ) end
delele atom sele .not. sph end
! FORCE RESIDs TO BE SEQUENTIALLY NUMBERED
join WAT renum

! MAKE 1/4 BY ROTATION
gener T dupl WAT
coor dupl sele segid WAT end sele segid T end
coor rota zdir 1.0 phi 90. sele segid T end
join WAT T renum

! MAKE 1/2 BY ROTATION
gener T dupl WAT
coor dupl sele segid WAT end sele segid T end
coor rota ydir 1.0 phi 90. sele segid T end
join WAT T renum

! FINAL ROTATION
gener T dupl WAT
coor dupl sele segid WAT end sele segid T end
coor rota xdir 1.0 phi 180. sele segid T end
join WAT T renum

! SETUP SHAKE, INITAL MIN
shake bonh param
coor copy comp
coor shake
mini sd nstep 75 nprint 5
coor copy comp
coor shake
mini abnr nstep 150 nprint 10

! SAVE PSF, SPHERE COOR
open unit 2 write card name sphr20.psf
write psf card unit 2
* 20 A sphere of ?NRES waters
*

open unit 2 write card name sphr20.crd
write coor card unit 2
* 20 A sphere of ?NRES waters; e = ?ENER
*

! SETUP RHDO, CRYSTAL MIN
crystal define rhdo 36. 36. 36. 60. 90. 60.
crystal build cutoff 20. noper 0
image byres

mini sd nstep 100 nprint 5 cutim 14. imgfrq 5
mini abnr nstep 200 nprint 10 imgfrq 10

! SAVE RHDO COOR
open unit 2 write card name rhdo36.crd
write coor card unit 2
* d=36 A RHDO from r=20 A sphere, ?NRES waters; e = ?ENER
*

stop


Rick Venable
computational chemist

Re: make RHDO via spherical cut from a box
rmv #1196 01/17/05 05:54 AM
Joined: May 2004
Posts: 222
C
Forum Member
Offline
Forum Member
C
Joined: May 2004
Posts: 222
open unit 2 read card name "../../W34tst/box34.crd"

May i know where can one get box34.crd?


CHARMM 30b1 driven by 1/ Xeon (32 bits) 2/ Redhat 7.3 (32 bits) with a Quadrics-modified 2.4-18-5 kernel 3/ Chuan, with 95% of the mentorship coming from great scientists frequenting this forum. 4/ Gracious support from the forum.
Re: make RHDO via spherical cut from a box
chuan #1197 01/17/05 06:12 AM
Joined: May 2004
Posts: 222
C
Forum Member
Offline
Forum Member
C
Joined: May 2004
Posts: 222
The dimensions seem to be not flexible enough to be able to cater to different dimensional demands?


CHARMM 30b1 driven by 1/ Xeon (32 bits) 2/ Redhat 7.3 (32 bits) with a Quadrics-modified 2.4-18-5 kernel 3/ Chuan, with 95% of the mentorship coming from great scientists frequenting this forum. 4/ Gracious support from the forum.
Re: make RHDO via spherical cut from a box
chuan #1198 01/17/05 07:34 PM
Joined: Sep 2003
Posts: 8,499
rmv Offline OP
Forum Member
OP Offline
Forum Member
Joined: Sep 2003
Posts: 8,499
There are several water boxes in the CHARMM distributions, in the test/data subdir; the files tip125.crd and tip216.crd have the cube edge length in the header. The latter can be replicated 2x2x2 to make a larger cube of almost 38 A edge. Any cubic box of water can be used, as long as it's edge length is longer than the sphere radius (20.0) specified in the command

! CUT A 1/8 SPHERICAL SECTION (+++ OCTANT)
define sph sele .byres. ( point 0. 0. 0. cut 20.0 ) end

By changing the value used for cut above, any size sphere with a radius less than the box edge can be created. For larger spheres, start with a larger size box. The dimensions are up to the user; if being used to prepare one of the "near sphere" lattice types RHDO or OCTA full of water, the radius is determined by the intended size (volume) of the unit cell. It's up to the user (you) to determine the edge size of the RHDO or OCTA shape (e.g. longest dimension of protein plus 16 A), compute the volume using the formula given in crystl.doc, and then compute the radius of a sphere with the same volume as the unit cell.


Rick Venable
computational chemist

Re: make RHDO via spherical cut from a box
rmv #23445 02/16/10 08:02 PM
Joined: Jan 2010
Posts: 15
Forum Member
Offline
Forum Member
Joined: Jan 2010
Posts: 15
If I started with a box with edge lengths longer than the diameter of the sphere I need, could I just center the box at the origin instead of this step:


----
! MOVE CORNER TO ORIGIN; NPT EQUILIBRATED BOX EDGE
set a 34.1995
calc a2 = 0.5 * @A
coor tran xdir @A2 ydir @A2 zdir @A2
----

and skip all of the rotation parts?


I already tried it and visualized the result, but I wanted to check if there is anything wrong with doing it that way?


- Kellen -
Re: make RHDO via spherical cut from a box
Kellen #23446 02/16/10 08:13 PM
Joined: Sep 2003
Posts: 8,499
rmv Offline OP
Forum Member
OP Offline
Forum Member
Joined: Sep 2003
Posts: 8,499
Certainly; as noted, the above does not center the box, it moves a corner to the origin. COOR ORIENT NOROT will center the box easily.


Rick Venable
computational chemist

Re: make RHDO via spherical cut from a box
rmv #23500 02/25/10 04:22 AM
Joined: Jan 2010
Posts: 15
Forum Member
Offline
Forum Member
Joined: Jan 2010
Posts: 15
I have created a RHDO of waters using the script successfully, however I cannot get it to produce more than 18 transformations. I am using a sphere of radius 54 to make an RHDO with length 98, and my crystal cutoff was 50. I tried increasing it to 60, but the SHAKE error was too large and it terminated. I'm trying at 55 right now.

The reason I'm trying to get 26 is because I understand that 26 transformations are required to use periodic boundary conditions... correct?


- Kellen -
Re: make RHDO via spherical cut from a box
Kellen #23501 02/25/10 05:15 AM
Joined: Sep 2003
Posts: 8,499
rmv Offline OP
Forum Member
OP Offline
Forum Member
Joined: Sep 2003
Posts: 8,499
The minimum number of transformations depends on the lattice shape; it is 26 for shapes with square corners (CUBIC, TETR, ORTH), but it is 12 for an RHDO lattice, and 14 for an OCTA lattice.

It's sounds like you're manipulating the wrong cutoff-- the CUTOFF keyword of CRYSTAL BUILD (crystl.doc) controls the number of image transformations, and I wouldn't expect changing it to lead to SHAKE errors.

The image list cutoff, CUTIM (images.doc), should be equal to CUTNB (nbonds.doc) or slightly larger, typically 14 to 18 Angstroms.


Rick Venable
computational chemist

Re: make RHDO via spherical cut from a box
rmv #23503 02/25/10 06:15 AM
Joined: Jan 2010
Posts: 15
Forum Member
Offline
Forum Member
Joined: Jan 2010
Posts: 15
thanks! that's precisely what I needed to know.


- Kellen -

Moderated by  lennart, rmv 

Link Copied to Clipboard
Powered by UBB.threads™ PHP Forum Software 7.7.4
(Release build 20200307)
Responsive Width:

PHP: 5.6.33-0+deb8u1 Page Time: 0.011s Queries: 32 (0.007s) Memory: 0.9634 MB (Peak: 1.0875 MB) Data Comp: Off Server Time: 2020-09-28 02:02:40 UTC
Valid HTML 5 and Valid CSS